{"id":294,"date":"2010-10-30T12:20:10","date_gmt":"2010-10-30T11:20:10","guid":{"rendered":"http:\/\/www.walkingrandomly.com\/?p=294"},"modified":"2020-10-22T15:33:03","modified_gmt":"2020-10-22T14:33:03","slug":"complex-power-towers-or-mucking-around-with-mathematica","status":"publish","type":"post","link":"https:\/\/walkingrandomly.com\/?p=294","title":{"rendered":"Complex Power Towers (Or ‘mucking around with Mathematica’)"},"content":{"rendered":"

Some time ago now, Sam Shah of Continuous Everywhere but Differentiable Nowhere<\/a> fame discussed the standard method of obtaining the square root of the imaginary unit<\/a>, i, and in the ensuing discussion thread someone asked the question “What is i^i – that is what is i to the power i?”<\/p>\n

Sam immediately came back with the answer e^(-pi\/2) = 0.207879…. which is one<\/strong> of the answers but as pointed out by one of his readers, Adam Glesser, this is just one of the infinite number of potential answers that all have the form e^{-(2k+1) pi\/2} where k is an integer. Sam’s answer is the principle value<\/strong><\/a> of i^i (incidentally this is the value returned by google calculator if you google i^i – It is also the value returned by Mathematica<\/a> and MATLAB<\/a>). Life gets a lot more complicated when you move to the complex plane but it also gets a lot more interesting too.<\/p>\n

While on the train into work one morning I was thinking about Sam’s blog post and wondered what the principal value of i^i^i (i to the power i to the power i) was equal to. Mathematica quickly provided the answer:<\/p>\n

N[I^I^I]\n0.947159+0.320764 I<\/pre>\n
So i is imaginary, i^i is real and i^i^i is imaginary again. Would i^i^i^i be real I wondered – would be fun if it was. Let’s see:<\/p>\n
N[I^I^I^I]\n0.0500922+0.602117 I<\/pre>\n
gah – a conjecture bites the dust – although if I am being honest it wasn’t a very good one.\u00a0 Still, since I have started making ‘power towers’ I may as well continue and see what I can see. Why am I calling them power towers? Well, the calculation above could be written as follows:<\/p>\n
\"small<\/p>\n
As I add more and more powers, the left hand side of the equation will tower up the page….Power Towers.\u00a0 We now have a sequence of the first four power towers of i:<\/p>\n
i = i\ni^i = 0.207879\ni^i^i = 0.947159 + 0.32076 I\ni^i^i^i = 0.0500922+0.602117 I<\/pre>\n
Sequences of power towers<\/h3>\n
“Will this sequence converge or diverge?”, I wondered.\u00a0 I wasn’t in the mood to think about a rigorous mathematical proof, I just wanted to play so I turned back to Mathematica.\u00a0 First things first, I needed to come up with a way of making an arbitrarily large power tower without having to do a lot of typing.\u00a0 Mathematica’s Nest function came to the rescue and the following function allows you to create a power tower of any size for any number, not just i.<\/p>\n
tower[base_, size_] := Nest[N[(base^#)] &, base, size]<\/pre>\n
Now I can find the first term of my series by doing<\/p>\n
In[1]:= tower[I, 0]\n\nOut[1]= I<\/pre>\n
Or the 5th term by doing<\/p>\n
In[2]:= tower[I, 4] \n\nOut[2]= 0.387166 + 0.0305271 I<\/pre>\n
To investigate convergence I needed to create a table of these. Maybe the first 100 towers would do:<\/p>\n
ColumnForm[\n Table[tower[I, n], {n, 1, 100}]\n ]<\/pre>\n
The last few values given by the command above are<\/p>\n
0.438272+ 0.360595 I\n0.438287+ 0.360583 I\n0.438287+ 0.3606 I\n0.438275+ 0.360591 I\n0.438289+ 0.360588 I<\/pre>\n
Now this is interesting – As I increased the size of the power tower, the result seemed to be converging to around 0.438 + 0.361 i. Further investigation confirms that the sequence of power towers of i converges to 0.438283+ 0.360592 i.\u00a0 If you were to ask me to guess what I thought would happen with large power towers like this then I would expect them to do one of three things – diverge to infinity, stay at 1 forever or quickly converge to 0 so this is unexpected behaviour (unexpected to me at least).<\/p>\n
They converge, but how?<\/h3>\n
My next thought was ‘How does it converge to this value?\u00a0 In other words, ‘What path through the complex plane does this sequence of power towers take?”\u00a0 Time for a graph:<\/p>\n
tower[base_, size_] := Nest[N[(base^#)] &, base, size];\ncomplexSplit[x_] := {Re[x], Im[x]};\nListPlot[Map[complexSplit, Table[tower[I, n], {n, 0, 49, 1}]],\n PlotRange -> All]<\/pre>\n
\"Power<\/p>\n
Who would have thought you could get a spiral from power towers? Very nice! So the next question is ‘What would happen if I took a different complex number as my starting point?’ For example – would power towers of (0.5 + i) converge?’<\/p>\n
The answer turns out to be yes – power towers of (0.5 + I) converge to 0.541199+ 0.40681 I but the resulting spiral looks rather different from the one above.<\/p>\n
tower[base_, size_] := Nest[N[(base^#)] &, base, size];\ncomplexSplit[x_] := {Re[x], Im[x]};\nListPlot[Map[complexSplit, Table[tower[0.5 + I, n], {n, 0, 49, 1}]],\n PlotRange -> All]<\/pre>\n
\"AnotherThe zoo of power tower spirals<\/h3>\n
So, taking power towers of two different complex numbers results in two qualitatively different ‘convergence spirals’. I wondered how many different spiral types I might find if I consider the entire complex plane?\u00a0 I already have all of the machinery I need to perform such an investigation but investigation is much more fun if it is interactive.\u00a0 Time for a Manipulate<\/p>\n
complexSplit[x_] := {Re[x], Im[x]};\n\ntower[base_, size_] := Nest[N[(base^#)] &, base, size];\n\ngeneratePowerSpiral[p_, nmax_] :=\n  Map[complexSplit, Table[tower[p, n], {n, 0, nmax-1, 1}]];\n\nManipulate[const = p[[1]] + p[[2]] I;\n ListPlot[generatePowerSpiral[const, n],\n PlotRange -> {{-2, 2}, {-2, 2}}, Axes -> ax,\n Epilog -> Inset[Framed[const], {-1.5, -1.5}]], {{n, 100,\n \"Number of terms\"}, 1, 200, 1,\n Appearance -> \"Labeled\"}, {{ax, True, \"Show axis\"}, {True,\n False}}, {{p, {0, 1.5}}, Locator}]<\/pre>\n
\"Power
\nAfter playing around with this Manipulate for a few seconds it became clear to me that there is quite a rich diversity of these convergence spirals. Here are a couple more<\/p>\n
\"Power<\/p>\n
Some of them take a lot longer to converge than others and then there are those that don’t converge at all:<\/p>\n
\"non<\/p>\n
Optimising the code a little<\/h3>\n
Before I could investigate convergence any further, I had a problem to solve: Sometimes the Manipulate would completely freeze and a message eventually popped up saying “One or more dynamic objects are taking excessively long to finish evaluating……”\u00a0 What was causing this I wondered?<\/p>\n
Well, some values give overflow errors:<\/p>\n
In[12]:= generatePowerSpiral[-1 + -0.5 I, 200]\n\nGeneral::ovfl: Overflow occurred in computation. >>\nGeneral::ovfl: Overflow occurred in computation. >>\nGeneral::ovfl: Overflow occurred in computation. >>\nGeneral::stop: Further output of General::ovfl will be suppressed during this calculation. >><\/pre>\n
Could errors such as this be making my Manipulate unstable?\u00a0 Let’s see how long it takes Mathematica to deal with the example above<\/p>\n
AbsoluteTiming[ListPlot[generatePowerSpiral[-1  -0.5 I, 200]]]<\/pre>\n
On my machine, the above command typically takes around 0.08 seconds to complete compared to 0.04 seconds for a tower that converges nicely; it’s slower but not so slow that it should break Manipulate.\u00a0 Still, let’s fix it anyway.<\/p>\n
Look at the sequence of values that make up this problematic power tower<\/p>\n
generatePowerSpiral[-0.8 + 0.1 I, 10]\n\n{{-0.8, 0.1}, {-0.668442, -0.570216}, {-2.0495, -6.11826},\n{2.47539*10^7,1.59867*10^8}, {2.068155430437682*10^-211800874,\n-9.83350984373519*10^-211800875}, {Overflow[], 0}, {Indeterminate,\n  Indeterminate}, {Indeterminate, Indeterminate}, {Indeterminate,\n  Indeterminate}, {Indeterminate, Indeterminate}}<\/pre>\n
Everything is just fine until the term {Overflow[],0} is reached; after which we are just wasting time. Recall that the functions I am using to create these sequences are<\/p>\n
complexSplit[x_] := {Re[x], Im[x]};\ntower[base_, size_] := Nest[N[(base^#)] &, base, size];\ngeneratePowerSpiral[p_, nmax_] :=\n  Map[complexSplit, Table[tower[p, n], {n, 0, nmax-1, 1}]];<\/pre>\n
The first thing I need to do is break out of tower’s Nest function as soon as the result stops being a complex number and the NestWhile<\/a> function allows me to do this.\u00a0 So, I could redefine the tower function to be<\/p>\n
tower[base_, size_] :=\n NestWhile[N[(base^#)] &, base, MatchQ[#, _Complex] &, 1, size]<\/pre>\n
However, I can do much better than that since my code so far is massively inefficient.\u00a0 Say I already have the first n terms of a tower sequence; to get the (n+1)th term all I need to do is a single power operation but my code is starting from the beginning and doing n power operations instead.\u00a0 So, to get the 5th term, for example, my code does this<\/p>\n
I^I^I^I^I<\/pre>\n
instead of<\/p>\n
(4th term)^I<\/pre>\n
The function I need to turn to is yet another variant of Nest – NestWhileList<\/a><\/p>\n
fasttowerspiral[base_, size_] :=\n Quiet[Map[complexSplit,\n NestWhileList[N[(base^#)] &, base, MatchQ[#, _Complex] &, 1,\n size, -1]]];<\/pre>\n
The Quiet function is there to prevent Mathematica from warning me about the Overflow error.\u00a0 I could probably do better than this and catch the Overflow error coming before it happens but since I’m only mucking around, I’ll leave that to an interested reader.\u00a0 For now it’s enough for me to know that the code is much faster than before:<\/p>\n
(*Original Function*)\nAbsoluteTiming[generatePowerSpiral[I, 200];]\n\n{0.036254, Null}<\/pre>\n
(*Improved Function*)\nAbsoluteTiming[fasttowerspiral[I, 200];]\n\n{0.001740, Null}<\/pre>\n
A factor of 20 will do nicely!<\/p>\n
Making Mathematica faster by making it stupid<\/h3>\n
I’m still not done though. Even with these optimisations, it can take a massive amount of time to compute some of these power tower spirals. For example<\/p>\n
spiral = fasttowerspiral[-0.77 - 0.11 I, 100];<\/pre>\n
takes 10 seconds on my machine which is thousands of times slower than most towers take to compute. What on earth is going on? Let’s look at the first few numbers to see if we can find any clues<\/p>\n
In[34]:= spiral[[1 ;; 10]]\n\nOut[34]= {{-0.77, -0.11}, {-0.605189, 0.62837}, {-0.66393,\n  7.63862}, {1.05327*10^10,\n  7.62636*10^8}, {1.716487392960862*10^-155829929,\n  2.965988537183398*10^-155829929}, {1., \\\n-5.894184073663391*10^-155829929}, {-0.77, -0.11}, {-0.605189,\n  0.62837}, {-0.66393, 7.63862}, {1.05327*10^10, 7.62636*10^8}}<\/pre>\n
The first pair that jumps out at me is {1.71648739296086210^-155829929, 2.965988537183398<\/em>10^-155829929} which is so close to {0,0} that it’s not even funny! So close, in fact, that they are not even double precision<\/a> numbers any more. Mathematica has realised that the calculation was going to underflow<\/a> and so it caught it and returned the result in arbitrary precision<\/a>.<\/p>\n
Arbitrary precision calculations are MUCH slower than double precision ones and this is why this particular calculation takes so long. Mathematica is being very clever but its cleverness is costing me a great deal of time and not adding much to the calculation in this case. I reckon that I want Mathematica to be stupid this time and so I’ll turn off its underflow safety net.<\/p>\n
SetSystemOptions[\"CatchMachineUnderflow\" -> False]<\/pre>\n
Now our problematic calculation takes 0.000842 seconds rather than 10 seconds which is so much faster that it borders on the astonishing. The results seem just fine too!<\/p>\n
When do the power towers converge?<\/h3>\n
We have seen that some towers converge while others do not. Let S be the set of complex numbers which lead to convergent power towers. What might S look like? To determine that I have to come up with a function that answers the question ‘For a given complex number z, does the infinite power tower converge?’ The following is a quick stab at such a function<\/p>\n
convergeQ[base_, size_] :=\n  If[Length[\n     Quiet[NestWhileList[N[(base^#)] &, base, Abs[#1 - #2] > 0.01 &,\n       2, size, -1]]] < size, 1, 0];<\/pre>\n
The tolerance I have chosen, 0.01, might be a little too large but these towers can take ages to converge and I’m more interested in speed than accuracy right now so 0.01 it is. convergeQ<\/strong> returns 1 when the tower seems to converge in at most size<\/strong> steps and 0 otherwise.:<\/p>\n
In[3]:= convergeQ[I, 50]\nOut[3]= 1\n\nIn[4]:= convergeQ[-1 + 2 I, 50]\nOut[4]= 0<\/pre>\n
So, let’s apply this to a section of the complex plane.<\/p>\n
towerFract[xmin_, xmax_, ymin_, ymax_, step_] :=\n ArrayPlot[\n Table[convergeQ[x + I y, 50], {y, ymin, ymax, step}, {x, xmin, xmax,step}]]\ntowerFract[-2, 2, -2, 2, 0.1]<\/pre>\n
\"Rough<\/p>\n
That looks like it might be interesting, possibly even fractal, behaviour but I need to increase the resolution and maybe widen the range to see what’s really going on. That’s going to take quite a bit of calculation time so I need to optimise some more.<\/p>\n
Going Parallel<\/h3>\n
There is no point in having machines with two, four or more processor cores if you only ever use one and so it is time to see if we can get our other cores in on the act.<\/p>\n
It turns out that this calculation is an example of a so-called embarrassingly parallel<\/a> problem and so life is going to be particularly easy for us.\u00a0 Basically, all we need to do is to give each core its own bit of the complex plane to work on, collect the results at the end and reap the increase in speed. Here’s the full parallel version of the power tower fractal code<\/p>\n
(*Complete Parallel version of the power tower fractal code*)\n\nconvergeQ[base_, size_] :=\n If[Length[\n Quiet[NestWhileList[N[(base^#)] &, base, Abs[#1 - #2] > 0.01 &,\n 2, size, -1]]] < size, 1, 0];\n\nLaunchKernels[];\nDistributeDefinitions[convergeQ];\nParallelEvaluate[SetSystemOptions[\"CatchMachineUnderflow\" -> False]];\n\ntowerFractParallel[xmin_, xmax_, ymin_, ymax_, step_] :=\n ArrayPlot[\n ParallelTable[\n convergeQ[x + I y, 50], {y, ymin, ymax, step}, {x, xmin, xmax, step}\n, Method -> \"CoarsestGrained\"]]<\/pre>\n
This code is pretty similar to the single processor version so let’s focus on the parallel modifications.\u00a0 My convergeQ<\/strong> function is no different to the serial version so nothing new to talk about there.\u00a0 So, the first new code is<\/p>\n
LaunchKernels[];<\/pre>\n
This launches a set of parallel Mathematica kernels. The amount that actually get launched depends on the number of cores on your machine.\u00a0 So, on my dual core laptop I get 2 and on my quad core desktop I get 4.<\/p>\n
DistributeDefinitions[convergeQ];<\/pre>\n
All of those parallel kernels are completely clean in that they don’t know about my user defined convergeQ<\/strong> function. This line sends the definition of convergeQ to all of the freshly launched parallel kernels.<\/p>\n
ParallelEvaluate[SetSystemOptions[\"CatchMachineUnderflow\" -> False]];<\/pre>\n
Here we turn off Mathematica’s machine underflow safety net on all of our parallel kernels using the ParallelEvaluate function.<\/p>\n
That’s all that is necessary to set up the parallel environment.\u00a0 All that remains is to change Map<\/strong> to ParallelMap<\/strong> and to add the argument Method -> “CoarsestGrained”<\/strong> which basically says to Mathematica ‘Each sub-calculation will take a tiny amount of time to perform so you may as well send each core lots to do at once’<\/strong> (click here for a blog post of mine<\/a> where this is discussed further).<\/p>\n
That’s all it took to take this embarrassingly parallel problem from a serial calculation to a parallel one.\u00a0 Let’s see if it worked.\u00a0 The test machine for what follows contains a T5800 Intel Core 2 Duo CPU running at 2Ghz on Ubuntu (if you want to repeat these timings then I suggest you read this blog post first<\/a> or you may find the parallel version going slower than the serial one).\u00a0 I’ve suppressed the output of the graphic since I only want to time calculation and not rendering time.<\/p>\n
(*Serial version*)\nIn[3]= AbsoluteTiming[towerFract[-2, 2, -2, 2, 0.1];]\nOut[3]= {0.672976, Null}\n\n(*Parallel version*)\nIn[4]= AbsoluteTiming[towerFractParallel[-2, 2, -2, 2, 0.1];]\nOut[4]= {0.532504, Null}\n\nIn[5]= speedup = 0.672976\/0.532504\nOut[5]= 1.2638<\/pre>\n
I was hoping for a bit more than a factor of 1.26 but that’s the way it goes with parallel programming sometimes. The speedup factor gets a bit higher if you increase the size of the problem though. Let’s increase the problem size by a factor of 100.<\/p>\n
towerFractParallel[-2, 2, -2, 2, 0.01]<\/p>\n
The above calculation took 41.99 seconds compared to 63.58 seconds for the serial version resulting in a speedup factor of around 1.5 (or about 34% depending on how you want to look at it).
\n\"Power<\/p>\n
Other optimisations<\/h3>\n
I guess if I were really serious about optimising this problem then I could take advantage of the symmetry along the x axis or maybe I could utilise the fact that if one point in a convergence spiral converges then it follows that they all do. Maybe there are more intelligent ways to test for convergence or maybe I’d get a big speed increase from programming in C or F#?\u00a0 If anyone is interested in having a go at improving any of this and succeeds then let me know.<\/p>\n
I’m not going to pursue any of these or any other optimisations, however, since the above exploration is what I achieved in a single train journey to work (The write-up took rather longer though). I didn’t know where I was going and I only worried about optimisation when I had to. At each step of the way the code was fast enough<\/strong> to ensure that I could interact with the problem at hand.<\/p>\n
Being mostly ‘fast enough’ with minimal programming effort is one of the reasons I like playing with Mathematica when doing explorations such as this.<\/p>\n
Treading where people have gone before<\/h3>\n
So, back to the power tower story. As I mentioned earlier, I did most of the above in a single train journey and I didn’t have access to the internet. I was quite excited that I had found a fractal from such a relatively simple system and very much felt like I had discovered something for myself. Would this lead to something that was publishable I wondered?<\/p>\n
Sadly not!<\/p>\n
It turns out that power towers have been thoroughly investigated and the act of forming a tower is called tetration<\/a>. I learned that when a tower converges there is an analytical formula that gives what it will converge to:<\/p>\n
\"h(z) = -\frac{W(-ln z)}{ln(z)\"<\/p>\n
Where W is the Lambert W function<\/a> (click here for a cool poster<\/a> for this function).\u00a0 I discovered that other people had already made Wolfram Demonstrations for power towers too<\/p>\n